## ## "Oh no!  Yet another filter!!"
### # 
## ## GEIMI.IRC  -  GeiMVeRumálið góða, sem fólk gæti hugsanlega skilið ef
# ###			það nennti að lesa allt upphátt...  %+]
## ##
### #		   The wonderful Language Of ALieNS, which people might 
## ##			understand if they read everything out loud..
# ###
^set eight_bit_characters on

@ geimi.wild  = [????]

@ geimi.sig.1  = []
@ geimi.lev.1  = [Crap level 1: Legible          Steypustig 1: Læsilegt]
@ geimi.from.1 = [gkwvpbnmdtzsGKWVPBNMDTZS!?-+\\\/:%\]\)\(\[\;\$&=69172583O0]
@ geimi.to.1   = [kgvwbpmntdszKGVWBPMNTDSZ?!+-\/\\%:\)\]\[\(\$\;=&967152380O]

@ geimi.sig.2  = []
@ geimi.lev.2  = [Crap level 2: Illegible        Steypustig 2: Ólæsilegt]
@ geimi.from.2 = [iloræðeuy,öúhxILR4ÆÐEUY.ÖÚHX$(geimi.from.1)]
@ geimi.to.2   = [liroðæue,yúöxhLI4RÐÆUE.YÚÖXH$(geimi.to.1)]

@ geimi.sig.3  = []
@ geimi.lev.3  = [Crap level 3: iRRiTaTinG cRaP  Steypustig 3: PiRRaNdI sTeYpa]
@ geimi.from.3 = [abcdefghijklmnopqrstuvwxyzABCDEFGHIJKLMNOPQRSTUVWXYZ1234567890!?-+\\\/:%\]\)\(\[\;\$&=><*']
@ geimi.to.3   = [zYxWU'SrQpOM<KjIGf*dCbAZyXwVu>sRqPoNmLkJiHgFeDcBa0987654321vhn?!+-\/\\%:\)\]\[\(\$\;=&TlEt]

@ geimi.sig   = [$geimi.sig.1]
@ geimi.lev   = [1]
@ geimi.from  = [$geimi.from.1]
@ geimi.to    = [$geimi.to.1]

alias geimi.trans {
        @ geimi.c2s1 = [$2-]
        @ geimi.c2s2 = index($0 $2-)  
        @ geimi.c2s3 = []
        while (geimi.c2s2 != -1) {
		@ geimi.c2s4 = index($mid($geimi.c2s2 1 $geimi.c2s1) $0)
                @ geimi.c2s3 = geimi.c2s3 ## [$left($geimi.c2s2 $geimi.c2s1)$mid($geimi.c2s4 1 $1)]
                @ geimi.c2s1 = mid(${geimi.c2s2 + 1} -1 $geimi.c2s1)
                @ geimi.c2s2 = index($0 $geimi.c2s1)
        }
        @ function_return = geimi.c2s3 ## geimi.c2s1
}

eval on #^window 00 "% *$(geimi.wild)*" {
	@ geimi.spo = [${match($(geimi.wild)% $0-) - 1}]
	@ geimi.tle = [${rmatch($($geimi.spo) *$(geimi.sig.1)* *$(geimi.sig.2)* *$(geimi.sig.3)*)}]
	if ([$1]==[***]) {
		@ geimi.fix = [ $(2-${geimi.spo - 1}) $geimi.trans($(geimi.to.$(geimi.tle)) $(geimi.from.$(geimi.tle)) $mid(8 -1 $(${geimi.spo}-)))]
	} {	@ geimi.fix = [$(1-${geimi.spo - 1}) $geimi.trans($(geimi.to.$(geimi.tle)) $(geimi.from.$(geimi.tle)) $mid(8 -1 $(${geimi.spo}-)))]
	}
	xecho -WINDOW $0 [G$(geimi.tle)]$geimi.fix 
}

alias g {
	if ([$0]!=[]) {
		if (!match($(K)% $0)) {
			send $(geimi.sig)$geimi.trans($geimi.from $geimi.to $0-)
		} {	$0-
		}
		xtype -LITERAL $(K)g $()
	}
}
alias gsay {
	say $(geimi.sig)$geimi.trans($geimi.from $geimi.to $0-)
}
alias gkick {
	if ((ischannel($0)) || ([$0]==[*])) {
		if ([$1]) {$(K)$(K)kick $0-1 G) $(geimi.sig)$geimi.trans($geimi.from $geimi.to $2-) \(G}
	} {	if ([$0]) {$(K)$(K)kick * $0 G) $(geimi.sig)$geimi.trans($geimi.from $geimi.to $1-) \(G}
	}
}
alias gquit {
	signoff $(geimi.sig)$geimi.trans($geimi.from $geimi.to $0-)
}
alias gme {
	me $(geimi.sig)$geimi.trans($geimi.from $geimi.to $0-)
}
alias gtopic {
	if ((ischannel($0)) || ([$0]==[*])) {
		$(K)$(K)topic $0 $(geimi.sig)$geimi.trans($geimi.from $geimi.to $1-)
	} { 	$(K)$(K)topic $C $(geimi.sig)$geimi.trans($geimi.from $geimi.to $0-)
	}
}
alias gmsg {
	msg $0 $(geimi.sig)$geimi.trans($geimi.from $geimi.to $1-)
}
alias gaway {
	away $0 $(geimi.sig)$geimi.trans($geimi.from $geimi.to $1-)
}
alias gecho {
	echo [GeiMi] $geimi.trans($geimi.from $geimi.to $0-)
}
alias glevel {
	if (match($0 1 2 3)) {
		@ geimi.lev  = [$0]
		@ geimi.from = [$(geimi.from.$0)]
		@ geimi.to   = [$(geimi.to.$0)]
		@ geimi.sig  = [$(geimi.sig.$0)]
	}
	echo [GeiMi] $(geimi.lev.$(geimi.lev))
}
alias ghelp {
	echo [GeiMi] Commands....
	echo [GeiMi]    misc:       $(K)g, $(K)gmsg, $(K)gquit, $(K)gaway, $(K)ghelp, $(K)ginfo
	echo [GeiMi]    channels:   $(K)gsay, $(K)gtopic, $(K)gme, $(K)gkick
	echo [GeiMi]    testing:    $(K)gecho
	echo [GeiMi]    crap level: $(K)glevel [1|2|3]
}
alias ghjalp {
	echo [GeiMi] Skipanir....
	echo [GeiMi]    ýmislegt:   $(K)g, $(K)gmsg, $(K)gquit, $(K)gaway, $(K)ghjalp, $(K)ginfo
	echo [GeiMi]    rásir:      $(K)gsay, $(K)gtopic, $(K)gme, $(K)gkick
	echo [GeiMi]    tilraunir:  $(K)gecho
	echo [GeiMi]    steypustig: $(K)glevel [1|2|3]
}

alias ginfo {
	gecho  Command list in english:  $geimi.trans($geimi.to $geimi.from $(K)ghelp)   |     GeiMi.iRC v2.2! 
	gecho  Skipanalisti á íslensku:  $geimi.trans($geimi.to $geimi.from $(K)ghjalp)  |   by JuGGLeR GeiMVeRa
}

ginfo